qmake教程介紹

這個教程可以教會你如何使用qmake。我們建議你看完這個教程之后讀一下qmake手冊。

開始很簡單

讓我們假設(shè)你已經(jīng)完成了你的應(yīng)用程序的一個基本實(shí)現(xiàn)，并且你已經(jīng)創(chuàng)建了下述文件：

• hello.cpp

• hello.h

• main.cpp

你可以在qt/qmake/example中發(fā)現(xiàn)這些文件。你對這個應(yīng)用程序的配置僅僅知道的另一件事是它是用Qt寫的。首先，使用你所喜歡的純文本編輯器，在qt/qmake/tutorial中創(chuàng)建一個叫做hello.pro的文件。你所要做的第一件事是添加一些行來告訴qmake關(guān)于你所開發(fā)的項目中的源文件和頭文件這一部分。

我們先把源文件添加到項目文件中。為了做到這點(diǎn)，你需要使用SOURCES變量。只要用SOURCES +=來開始一行，并且把hello.cpp放到它后面。你需要寫成這樣：

    SOURCES += hello.cpp

我們對項目中的每一個源文件都這樣做，直到結(jié)束：

    SOURCES += hello.cpp
    SOURCES += main.cpp

如果你喜歡使用像Make一樣風(fēng)格的語法，你也可以寫成這樣，一行寫一個源文件，并用反斜線結(jié)尾，然后再起新的一行：

    SOURCES = hello.cpp \
	      main.cpp

現(xiàn)在源文件已經(jīng)被列到項目文件中了，頭文件也必須添加。添加的方式和源文件一樣，除了變量名是HEADERS。

當(dāng)你做完這些時，你的項目文件就像現(xiàn)在這樣：

    HEADERS += hello.h
    SOURCES += hello.cpp 
    SOURCES += main.cpp 

目標(biāo)名稱是自動設(shè)置的，它被設(shè)置為和項目文件一樣的名稱，但是為了適合平臺所需要的后綴。舉例來說，加入項目文件叫做“hello.pro”，在Windows上的目標(biāo)名稱應(yīng)該是“hello.exe”，在Unix上應(yīng)該是“hello”。如果你想設(shè)置一個不同的名字，你可以在項目文件中設(shè)置它：

    TARGET = helloworld

最后一步是設(shè)置CONFIG變量。因為這是一個Qt應(yīng)用程序，我們需要把“qt”放到CONFIG這一行中，這樣qmake才會在連接的時候添加相關(guān)的庫，并且保證moc和uic的連編行也被包含到Makefile中。

最終完成的項目文件應(yīng)該是這樣的：

    CONFIG += qt
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 

你現(xiàn)在可以使用qmake來為你的應(yīng)用程序生成Makefile。在你的應(yīng)用程序目錄中，在命令行下輸入：

    qmake -o Makefile hello.pro

然后根據(jù)你所使用的編譯器輸入make或者nmake。

使應(yīng)用程序可以調(diào)試

應(yīng)用程序的發(fā)布版本不包含任何調(diào)試符號或者其它調(diào)試信息。在開發(fā)過程中，生成一個含有相關(guān)信息的應(yīng)用程序的調(diào)試版本是很有用處的。通過在項目文件的CONFIG變量中添加“debug”就可以很簡單地實(shí)現(xiàn)。

例如：

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 

像前面一樣使用qmake來生成一個Makefile并且你就能夠調(diào)試你的應(yīng)用程序了。

添加特定平臺的源文件

在編了幾個小時的程序之后，你也許開始為你的應(yīng)用程序編寫與平臺相關(guān)的部分，并且決定根據(jù)平臺的不同編寫不同的代碼。所以現(xiàn)在你有兩個信文件要包含到你的項目文件中－hello_win.cpp和hello_x11.cpp。我們不能僅僅把這兩個文件放到SOURCES變量中，因為那樣的話會把這兩個文件都加到Makefile中。所以我們在這里需要做的是根據(jù)qmake所運(yùn)行的平臺來使用相應(yīng)的作用域來進(jìn)行處理。

為Windows平臺添加的依賴平臺的文件的簡單的作用域看起來就像這樣：

    win32 {
	SOURCES += hello_win.cpp
    }

所以如果qmake運(yùn)行在Windows上的時候，它就會把hello_win.cpp添加到源文件列表中。如果qmake運(yùn)行在其它平臺上的時候，它會很簡單地把這部分忽略。現(xiàn)在接下來我們要做的就是添加一個X11依賴文件的作用域。

當(dāng)你做完了這部分，你的項目文件應(yīng)該和這樣差不多：

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 
    win32 {
	SOURCES += hello_win.cpp
    }
    x11 {
	SOURCES += hello_x11.cpp
    }

像前面一樣使用qmake來生成Makefile。

如果一個文件不存在，停止qmake

如果某一個文件不存在的時候，你也許不想生成一個Makefile。我們可以通過使用exists()函數(shù)來檢查一個文件是否存在。我們可以通過使用error()函數(shù)把正在運(yùn)行的qmake停下來。這和作用域的工作方式一樣。只要很簡單地用這個函數(shù)來替換作用域條件。對main.cpp文件的檢查就像這樣：

    !exists( main.cpp ) {
	error( "No main.cpp file found" )
    }

“!”用來否定這個測試，比如，如果文件存在，exists( main.cpp )是真，如果文件不存在，!exists( main.cpp )是真。

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 
    win32 {
	SOURCES += hello_win.cpp
    }
    x11 {
	SOURCES += hello_x11.cpp
    }
    !exists( main.cpp ) {
	error( "No main.cpp file found" )
    }

像前面一樣使用qmake來生成Makefile。如果你臨時改變main.cpp的名稱，你會看到信息，并且qmake會停止處理。

檢查多于一個的條件

假設(shè)你使用Windows并且當(dāng)你在命令行運(yùn)行你的應(yīng)用程序的時候你想能夠看到qDebug()語句。除非你在連編你的程序的時候使用console設(shè)置，你不會看到輸出。我們可以很容易地把console添加到CONFIG行中，這樣在Windows下，Makefile就會有這個設(shè)置。但是如果告訴你我們只是想在當(dāng)我們的應(yīng)用程序運(yùn)行在Windows下并且當(dāng)debug已經(jīng)在CONFIG行中的時候，添加console。這需要兩個嵌套的作用域；只要生成一個作用域，然后在它里面再生成另一個。把設(shè)置放在最里面的作用域里，就像這樣：

    win32 {
	debug {
	    CONFIG += console
	}
    }

嵌套的作用域可以使用冒號連接起來，所以最終的項目文件看起來像這樣：

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 
    win32 {
	SOURCES += hello_win.cpp
    }
    x11 {
	SOURCES += hello_x11.cpp
    }
    !exists( main.cpp ) {
	error( "No main.cpp file found" )
    }
    win32:debug {
	CONFIG += console
    }

就這些了！你現(xiàn)在已經(jīng)完成了qmake的教程，并且已經(jīng)準(zhǔn)備好為你的開發(fā)項目寫項目文件了。

<!-- eof -->