qmake高級概念

迄今為止，我們見到的qmake項目文件都非常簡單，僅僅是一些name = value和name += value的列表行。qmake提供了很多更強大的功能，比如你可以使用一個簡單的項目文件來為多個平臺生成makefile。

操作符

到目前為止，你已經看到在項目文件中使用的=操作符和+=操作符。這里能夠提供更多的可供使用的操作符，但是其中的一些需要謹慎地使用，因為它們也許會比你期待的改變的更多。

“=”操作符

這個操作符簡單分配一個值給一個變量。使用方法如下：

    TARGET = myapp

這將會設置TARGET變量為myapp。這將會刪除原來對TARGET的任何設置。

“+=”操作符

這個操作符將會向一個變量的值的列表中添加一個值。使用方法如下：

    DEFINES += QT_DLL

這將會把QT_DLL添加到被放到makefile中的預處理定義的列表中。

“-=”操作符

這個操作符將會從一個變量的值的列表中移去一個值。使用方法如下：

    DEFINES -= QT_DLL

這將會從被放到makefile中的預處理定義的列表中移去QT_DLL。

“*=”操作符

這個操作符僅僅在一個值不存在于一個變量的值的列表中的時候，把它添加進去。使用方法如下：

    DEFINES *= QT_DLL

只用在QT_DLL沒有被定義在預處理定義的列表中時，它才會被添加進去。

“~=”操作符

這個操作符將會替換任何與指定的值的正則表達式匹配的任何值。使用方法如下：

    DEFINES ~= s/QT_[DT].+/QT

這將會用QT來替代任何以QT_D或QT_T開頭的變量中的QT_D或QT_T。

作用域

作用域和“if”語句很相似，如果某個條件為真，作用域中的設置就會被處理。作用域使用方法如下：

    win32 {
        DEFINES += QT_DLL
    }

上面的代碼的作用是，如果在Windows平臺上使用qmake，QT_DLL定義就會被添加到makefile中。如果在Windows平臺以外的平臺上使用qmake，這個定義就會被忽略。你也可以使用qmake執(zhí)行一個單行的條件/任務，就像這樣：

    win32:DEFINES += QT_DLL

比如，假設我們想在除了Windows平臺意外的所有平臺處理些什么。我們想這樣使用作用域來達到這種否定效果：

    !win32 {
        DEFINES += QT_DLL
    }

CONFIG行中的任何條目也都是一個作用域。比如，你這樣寫：

    CONFIG += warn_on

你將會得到一個稱作“warn_on”的作用域。這樣將會使在不丟失特定條件下可能所需的所有自定義設置的條件下，很容易地修改項目中的配置。因為你可能把你自己的值放到CONFIG行中，這將會為你的makefile而提供給你一個非常強大的配置工具。比如：

    CONFIG += qt warn_on debug
    debug {
        TARGET = myappdebug
    }
    release {
        TARGET = myapp
    }

在上面的代碼中，兩個作用域被創(chuàng)建，它們依賴于CONFIG行中設置的是什么。在這個例子中，debug在CONFIG行中，所以TARGET變量被設置為myappdebug。如果release在CONFIG行中，那么TARGET變量將會被設置為myapp。

當然也可以在處理一些設置之前檢查兩個事物。例如，如果你想檢查平臺是否是Windows并且線程設置是否被設定，你可以這樣寫：

    win32 {
        thread {
            DEFINES += QT_THREAD_SUPPORT
        }
    }

為了避免寫出許多嵌套作用域，你可以這樣使用冒號來嵌套作用域：

    win32:thread {
        DEFINES += QT_THREAD_SUPPORT
    }

一旦一個測試被執(zhí)行，你也許也要做else/elseif操作。這種情況下，你可以很容易地寫出復雜的測試。這需要使用特殊的“else”作用域，它可以和其它作用域進行組合（也可以向上面一樣使用冒號），比如：

    win32:thread {
        DEFINES += QT_THREAD_SUPPORT
    } else:debug {
        DEFINES += QT_NOTHREAD_DEBUG
    } else {
        warning("Unknown configuration")
    }

變量

到目前為止我們遇到的變量都是系統變量，比如DEFINES、SOURCES和HEADERS。你也可以為你自己創(chuàng)建自己的變量，這樣你就可以在作用域中使用它們了。創(chuàng)建自己的變量很容易，只要命名它并且分配一些東西給它。比如：

    MY_VARIABLE = value

現在你對你自己的變量做什么是沒有限制的，同樣地，qmake將會忽略它們，除非需要在一個作用域中考慮它們。

你也可以通過在其它任何一個變量的變量名前加$$來把這個變量的值分配給當前的變量。例如：

    MY_DEFINES = $$DEFINES

現在MY_DEFINES變量包含了項目文件在這點時DEFINES變量的值。這也和下面的語句一樣：

 
    MY_DEFINES = $${DEFINES}

第二種方法允許你把一個變量和其它變量連接起來，而不用使用空格。qmake將允許一個變量包含任何東西（包括$(VALUE)，可以直接在makefile中直接放置，并且允許它適當地擴張，通常是一個環(huán)境變量）。無論如何，如果你需要立即設置一個環(huán)境變量，然后你就可以使用$$()方法。比如：

    MY_DEFINES = $$(ENV_DEFINES)

這將會設置MY_DEFINES為環(huán)境變量ENV_DEFINES傳遞給.pro文件地值。另外你可以在替換的變量里調用內置函數。這些函數（不會和下一節(jié)中列舉的測試函數混淆）列出如下：

join( variablename, glue, before, after )

這將會在variablename的各個值中間加入glue。如果這個變量的值為非空，那么就會在值的前面加一個前綴before和一個后綴after。只有variablename是必須的字段，其它默認情況下為空串。如果你需要在glue、before或者after中使用空格的話，你必須提供它們。

member( variablename, position )

這將會放置variablename的列表中的position位置的值。如果variablename不夠長，這將會返回一個空串。variablename是唯一必須的字段，如果沒有指定位置，則默認為列表中的第一個值。

find( variablename, substr )

這將會放置variablename中所有匹配substr的值。substr也可以是正則表達式，而因此將被匹配。

    MY_VAR = one two three four
    MY_VAR2 = $$join(MY_VAR, " -L", -L) -Lfive
    MY_VAR3 = $$member(MY_VAR, 2) $$find(MY_VAR, t.*)

MY_VAR2將會包含“-Lone -Ltwo -Lthree -Lfour -Lfive”，并且MYVAR3將會包含“three two three”。

system( program_and_args )

這將會返回程序執(zhí)行在標準輸出/標準錯誤輸出的內容，并且正像平時所期待地分析它。比如你可以使用這個來詢問有關平臺的信息。

    UNAME = $$system(uname -s)
    contains( UNAME, [lL]inux ):message( This looks like Linux ($$UNAME) to me )

測試函數

qmake提供了可以簡單執(zhí)行，但強大測試的內置函數。這些測試也可以用在作用域中（就像上面一樣），在一些情況下，忽略它的測試值，它自己使用測試函數是很有用的。

contains( variablename, value )

如果value存在于一個被叫做variablename的變量的值的列表中，那么這個作用域中的設置將會被處理。例如：

    contains( CONFIG, thread ) {
        DEFINES += QT_THREAD_SUPPORT
    }

如果thread存在于CONFIG變量的值的列表中時，那么QT_THREAD_SUPPORT將會被加入到DEFINES變量的值的列表中。

count( variablename, number )

如果number與一個被叫做variablename的變量的值的數量一致，那么這個作用域中的設置將會被處理。例如：

    count( DEFINES, 5 ) {
        CONFIG += debug
    }

error( string )

這個函數輸出所給定的字符串，然后會使qmake退出。例如：

    error( "An error has occured" )

文本“An error has occured”將會被顯示在控制臺上并且qmake將會退出。

exists( filename )

如果指定文件存在，那么這個作用域中的設置將會被處理。例如：

    exists( /local/qt/qmake/main.cpp ) {
        SOURCES += main.cpp
    }

如果/local/qt/qmake/main.cpp存在，那么main.cpp將會被添加到源文件列表中。

注意可以不用考慮平臺使用“/”作為目錄的分隔符。

include( filename )

項目文件在這一點時包含這個文件名的內容，所以指定文件中的任何設置都將會被處理。例如：

 
    include( myotherapp.pro )

myotherapp.pro項目文件中的任何設置現在都會被處理。

isEmpty( variablename )

這和使用count( variablename, 0 )是一樣的。如果叫做variablename的變量沒有任何元素，那么這個作用域中的設置將會被處理。例如：

    isEmpty( CONFIG ) {
        CONFIG += qt warn_on debug
    }

message( string )

這個函數只是簡單地在控制臺上輸出消息。

    message( "This is a message" )

文本“This is a message”被輸出到控制臺上并且對于項目文件的處理將會繼續(xù)進行。

system( command )

特定指令被執(zhí)行并且如果它返回一個1的退出值，那么這個作用域中的設置將會被處理。例如：

    system( ls /bin ) {
        SOURCES += bin/main.cpp
        HEADERS += bin/main.h
    }

所以如果命令ls /bin返回1，那么bin/main.cpp將被添加到源文件列表中并且bin/main.h將被添加到頭文件列表中。

infile( filename, var, val )

如果filename文件（當它被qmake自己解析時）包含一個值為val的變量var，那么這個函數將會返回成功。你也可以不傳遞第三個參數（val），這時函數將只測試文件中是否分配有這樣一個變量var。